Anleitung zur binären Armbanduhr

Eine Binäruhr zeigt die Uhrzeit als binär codierte Zahlen an. Zur Verdeutlichung hier ein Bild:

Jede Spalte der Anzeige entspricht einer Ziffer der Uhrzeit.

1. Spalte	2. Spalte	3. Spalte	4. Spalte
1	9	2	3

Daraus ergibt sich 19:23 Uhr

• 1 x ATtiny 4313-SU
• 1 x RTC-Modul RV 3029-C2
• 13 x LED in Wunschfarbe, z.B. blau (Größe 0603)
• 4 x Widerstand für die LEDs (0603, abhängig von LED-Farbe)
• 3 x 10 kOhm Widerstand 0603
• 3 x Taster, 6mm x 3.5mm x 4.5mm oder ähnlich kleine Größe (Bild)
• 1 x Doppelseitige Platine 0.5 oder 1.0mm dick
• 1 x Knopfzellenhalter für Typ 2032, Höhe etwa 4mm
• 1 x Knopfzelle 2032, 3V, 180mAh oder höher
• 1 x Uhrengehäuse (z.B. Klick)
• evtl. Silberdraht, Durchmesser 0.25mm – 0.4mm

Beim Multiplexing werden die Anoden bzw. Kathoden der LEDs verbunden, um I/O-Pins zu sparen. Für 9 LEDs benötigt man gewöhnlicherweise 9 Pins, um alle separat voneinander schalten zu können. Per Multiplexing sinkt die Anzahl der Pins auf 6.

Die LEDs werden reihenweise ein- und wieder ausgeschaltet. Dies geschieht mit so hoher Geschwindigkeit, dass es so aussieht, als würden alle Reihen auf einmal leuchten.

Zu Beginn ist es sinnvoll, sich erstmal eine Versuchsschaltung aufzubauen. Ich habe mir hierfür “Module” gebaut, die man ganz einfach auf ein Breadboard stecken kann.

RTC-Modul

LED-Modul

Die Haltbarkeit der Batterie hält bei normaler Benutzung ca. 1-2 Jahre.

Die Uhr besteht aus zwei Platinen, die durch Litzen verbunden sind.

Batteriehalter:

Eagle-Projekt

Uhrwerk:

Eagle-Projekt

An der Seite des Uhrengehäuses wurde eine Aussparung herausgeschnitten, um dort die drei Taster zur Steuerung der Uhr anzubringen.

Der mittlere Taster passt genau durch das schon vorhandene Loch im Armband. Die anderen beiden Taster liegen unter dem Gummi, können aber einfach betätigt werden.

Damit die I²C-Verbindung auch auf dem Attiny funktioniert, benötigt man die TinyWireM-Bibliothek (Download).

#include <TinyWireM.h>
#include <avr/sleep.h>
#include <avr/interrupt.h>
#define RV3029 0xAC/2
#define STR2BCD_ERROR 0xff

#define LED1 2
#define LED2 5
#define LED3 6
#define LED4 7

#define LAYER1 8
#define LAYER2 9
#define LAYER3 10
#define LAYER4 11

#define LIGHTSON 4
#define MINUTESBUTTON 3
#define HOURSBUTTON 1

byte stunde = 11;
byte minute = 41;
byte sekunde = 15;

int m;

void setup() {
  pinMode(LED1, OUTPUT);
  pinMode(LED2, OUTPUT);
  pinMode(LED3, OUTPUT);
  pinMode(LED4, OUTPUT);
  pinMode(LAYER1, OUTPUT); //must be low to open ground
  pinMode(LAYER2, OUTPUT); //must be low to open ground
  pinMode(LAYER3, OUTPUT); //must be low to open ground
  pinMode(LAYER4, OUTPUT); //must be low to open ground

  pinMode(LIGHTSON, INPUT);
  pinMode(MINUTESBUTTON, INPUT);
  pinMode(HOURSBUTTON, INPUT);

  digitalWrite(LAYER1, HIGH);
  digitalWrite(LAYER2, HIGH);
  digitalWrite(LAYER3, HIGH);
  digitalWrite(LAYER4, HIGH);
  digitalWrite(LIGHTSON, HIGH);
  TinyWireM.begin();
  TinyWireM.beginTransmission(RV3029);
  TinyWireM.send(0x02);
  TinyWireM.send(0x00);
  TinyWireM.send(0x00);
  TinyWireM.endTransmission();
  
  attachInterrupt(0, wakeUpNow, LOW); 
  
  setTime();
  getTime();
}

void sleepNow(){
    set_sleep_mode(SLEEP_MODE_PWR_DOWN);
    sleep_enable();
    attachInterrupt(0,wakeUpNow, LOW);
    ACSR |= _BV(ACD);
    MCUCR |= _BV(7) | _BV(2);
    //sleep_mode();
    digitalWrite(LAYER1, LOW);
  digitalWrite(LAYER2, LOW);
  digitalWrite(LAYER3, LOW);
  digitalWrite(LAYER4, LOW);
    sleep_cpu();
    sleep_disable();
    detachInterrupt(0); 
}

void wakeUpNow(){
  digitalWrite(LAYER1, HIGH);
  digitalWrite(LAYER2, HIGH);
  digitalWrite(LAYER3, HIGH);
  digitalWrite(LAYER4, HIGH);
}

void loop () {
//  if(digitalRead(LIGHTSON)==LOW){
//    delay(2);
//    if(digitalRead(LIGHTSON)==LOW){
      getTime();
      for(m=0; m<300; m++){
        setLEDS();
        boolean temp = getButtons();
        if(temp || !digitalRead(LIGHTSON)){
          m=0;
        }
      }
//    }
//  }
sleepNow();
}

void getTime(){
  TinyWireM.beginTransmission(RV3029);
  TinyWireM.send(0x08);
  TinyWireM.endTransmission();
  TinyWireM.requestFrom(RV3029, 3);
  sekunde = bcdToDec(TinyWireM.receive())& 0x7f;
  minute = bcdToDec(TinyWireM.receive())& 0x7f;
  stunde = bcdToDec(TinyWireM.receive())& 0x3f;
}

void setTime(){
  TinyWireM.beginTransmission(RV3029);
  TinyWireM.send(0x08);
  TinyWireM.send(decToBcd(sekunde));
  TinyWireM.send(decToBcd(minute));
  TinyWireM.send(decToBcd(stunde));
  TinyWireM.endTransmission();
}

boolean getButtons(){
  boolean temp = false;
  if(digitalRead(MINUTESBUTTON)==HIGH){
    delay(2);
    if(digitalRead(MINUTESBUTTON)==HIGH){
      incMinutes();
      delay(10);
      while(digitalRead(MINUTESBUTTON)){

      }
      temp = true;
    }
  }
  if(digitalRead(HOURSBUTTON)==HIGH){
    delay(2);
    if(digitalRead(HOURSBUTTON)==HIGH){
      incHours();
      delay(10);
      while(digitalRead(HOURSBUTTON)){

      }
      temp = true;
    }
  }
  return temp;
}

void incMinutes(){
  if(minute+1>=60){    
    minute=0;
  } 
  else {
    minute++;
  }
  setTime();
}

void incHours(){
  if(stunde+1>=24){
    stunde=0;
  } 
  else {
    stunde++;
  }
  setTime();
}

// Convert normal decimal numbers to binary coded decimal
byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}

// Convert binary coded decimal to normal decimal numbers
byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}

void setLEDS(){
  //layer1
  digitalWrite(LAYER1, LOW);
  digitalWrite(LED1, bitRead(stunde/10, 0));
  digitalWrite(LED2, bitRead(stunde%10, 0));
  digitalWrite(LED3, bitRead(minute/10, 0));
  digitalWrite(LED4, bitRead(minute%10, 0));
  waitTwoMillis(); //wait before kill power, because the last LED column get not as bright as the other ones
  digitalWrite(LAYER1, HIGH);
  clearLEDS();

  //layer2
  digitalWrite(LAYER2, LOW);
  digitalWrite(LED1, bitRead(stunde/10, 1));
  digitalWrite(LED2, bitRead(stunde%10, 1));
  digitalWrite(LED3, bitRead(minute/10, 1));
  digitalWrite(LED4, bitRead(minute%10, 1));
  waitTwoMillis();
  digitalWrite(LAYER2, HIGH);
  clearLEDS();

  //layer3
  digitalWrite(LAYER3, LOW);
  digitalWrite(LED2, bitRead(stunde%10, 2));
  digitalWrite(LED3, bitRead(minute/10, 2));
  digitalWrite(LED4, bitRead(minute%10, 2));
  waitTwoMillis();
  digitalWrite(LAYER3, HIGH);
  clearLEDS();

  //layer4
  digitalWrite(LAYER4, LOW);
  digitalWrite(LED2, bitRead(stunde%10, 3));
  digitalWrite(LED4, bitRead(minute%10, 3));
  waitTwoMillis();
  digitalWrite(LAYER4, HIGH);
  clearLEDS();
}

void clearLEDS(){
  digitalWrite(LED1, LOW);
  digitalWrite(LED2, LOW);
  digitalWrite(LED3, LOW);
  digitalWrite(LED4, LOW);
}

void waitTwoMillis(){
  delay(2);
}